软件下载 | 资讯教程 | 最近更新 | 下载排行 | 一键转帖 | 发布投稿
您的位置:最火下载站 > 设计在线 > 媒体动画 > Flash AS 入门教程-碰撞检测hitTest函数

Flash AS 入门教程-碰撞检测hitTest函数

  hitTest函数是用来检测两个物体或目标是否重叠和相交,如果相交或重叠,就执行相应的动作,这对于我们做一些互动的动画和游戏是非常有用。比如在做点鞭炮、射击等的动画时,就可以用hitTest的方法。

  源文件下载

  hitTest用法

  1、my_mc.hitTest(x, y, true[false])

  影片剪辑my_mc和由x,y指定的点击区域重叠或交叉,则执行(大括号中)命令。参数true是指my_mc的整个形状;false是指my_mc包括边框。

  2、my_mc.hitTest(target)

  影片剪辑my_mc与target的目标路径指定的实例交叉或重叠。target 参数通常表示带路径的实例名。

  实例应用

  例1 鼠标控制影片剪辑移动。鼠标在(坐标_xmouse, _ymouse)影片剪辑qiu_mc上(与qiu_mc重叠或交叉)时,qiu_mc向右移动10个象素。打开3.4.1.fla文件。

  在场景第1帧上的脚本为:

 qiu_mc.onEnterFrame = function() { //qiu_mc执行onEnterFrame事件处理函数;
  if (this.hitTest(_xmouse, _ymouse, false)) { 
          //如果鼠标坐标与qiu_mc交叉或重叠(鼠标在qiu_mc上)
  this._x += 10; //qiu_mc横坐标增加10个象素;
  }
  if (this._x>=500) { //qiu_mc横坐标大于或者等于500个象素时
   this._x = 0;   //重新设置qiu_mc横坐标为0;
  }
 };

  点击查看动画效果<

  注意,把碰撞函数中的参数false改为true,观测不同效果,加深对mc的形状与边框的理解。

  例2 打开3.4.2fla文件

  本例中,要把圆等6个图形拖到上面对应的文字上。6个图形分别是tx1_mc~~tx6_mc;6个对应的文字都是动态文本,名称分别是wz1~wz6.每个mc拖动的位置如果出错了能够自动回到原来的位置,当6个mc都能正确拖到对应位置上时,主时间轴从第1帧跳到第2帧,并给于文字说明。

  显然,我们只要在一个mc上的脚本写对了,其它5个mc就可以很方便的写出来。

  在主时间轴第1帧上写的脚本:

  stop();
  i=0 ; //设置用于记数的变量
  在圆(tx1_mc)上的脚本为:
   on (press) {       //鼠标按下时
    x = _x;        //把本mc的坐标赋给本mc下的变量x,y
    y = _y;
    startDrag(this, true); //拖动这个mc 
 }
   on (release) { //松开鼠标时
     stopDrag();//停止拖动这个mc
     if (this.hitTest(_root.wz1)) {  //如果这个mc和动态文本wz1重叠或相交;
       if (k != 1) {        //这时如果这个mc上的变量k不为1
         _root.i++;        //主时间轴上的变量i加1;
         k = 1;
       //在这个mc上设置变量k=1(使一个mc拖动正确时,主时间轴上的记数变量i只加1次)
       }
       if(_root.i==6){ //如果主时间轴上的记数变量i等于6时(图形都正确拖动完毕)
        _root.nextFrame();//主时间轴跳到下1帧停下;
       }
    } else { //如果这个mc和动态文本wz1不重叠或相交
     _x = x;//把这个mc的坐标设置为前面得到的这个mc的坐标的数值
     _y = y;
    }
  }

  我们可以检测这段代码的正确性,然后我们可以把这段代码复制在其他5个mc上,只消把其中的wz1改为相应的wz2~wz6即可。

  点击查看动画效果<

  既然这六个mc上的代码都非常接近,我们应该想办法用函数的办法来处理。这六个mc上的代码中只有拖动的mc不同以及检测的文本不同,因此,这个自定义函数应该有两个参数。

  例3 打开3.4.3fla文件.在主时间轴第1帧上加上如下代码:

   stop();
   i = 0;
   function stlx(md, mc) { //md为拖动的mc,mc为检测的文本
    stopDrag();
     if (md.hitTest(mc)) {
       if (md.k!=1) { //变量k是md上的,因此这里写成md.k
         i++;   //自定义函数是写在主时间轴上,因此主时间轴上的变量可以不用写路径
         md.k = 1;
        }
       if (i == 6) {
         nextFrame();
        }
    } else {
     md._x = md.x;
     md._y = md.y;
    }
  }

  在mc上的代码就可以大为简化

  在圆(tx1_mc)上的代码就可以写成:

  on (press) {
  x = _x;
  y = _y;
  startDrag(this, true);
 }
  on (release) {
   _root.stlx(this, _root.wz1);
   //是在mc上写的调函数脚本,因此这里的stlx()和wz1都应该加上路径。
 }
  把tx1_mc上的代码复制到其它5个mc上,只把其中的wz1换成wz2~~wz6就行了。
  为了可以重复做这个练习,在主时间轴第2帧上加上一个按扭,在按扭上加上:
  on (release) {
  prevFrame(); //回到第1帧
 }

  作业

  用事件处理函数改造例2中的源文件,要求:

  1、脚本都写在主时间轴的第1帧上,所有mc上都不写脚本;

  2、注意使用onPress,onRelease处理函数及循环语句。

  查看全套"Flash AS 高级教程"

    相关阅读
    网友评论